CONTAR.SI (y SUMAR.SI) Reloaded

CONTAR.SI nos retorna el número de celdas (o valores) que cumplen con determinado criterio dentro de determinado rango. La sintaxis es:

CONTAR.SI(rango, criterio)

Generalmente solo es usada en ejemplos como los siguientes:

=CONTAR.SI(A2:A30, 100);

=CONTAR.SI(B2:B20, "alguntexto");

=CONTAR.SI(C2:C40, "texto a" & "texto b"); o

=CONTAR.SI(D2:D50, C1)

Sin embargo, el argumento criterio es mucho más flexible. Podemos especificar expresiones lógicas, wildcards, fórmulas, valores lógicos, fechas... Estos son algunos ejemplos que muestran la potencia de la función al usar criterios complejos:

=CONTAR.SI(A2:A50, ">0") Devuelve el número de celdas con valores mayores a 0.

=CONTAR.SI(A2:A50, "<>1") Devuelve el número de celdas con valores distintos de 1.

=CONTAR.SI(A2:A50, "<" & B1) Devuelve el número de celdas con valores menores a la celda B1.

=CONTAR.SI(A2:A50, HOY()) Cuenta las celdas con fecha igual a la actual.

=CONTAR.SI(A2:A50, ">" & FECHA(2007,10,01)) Devuelve el número de celdas con fecha mayor (más reciente) a 01/10/2007. Ya hemos visto el uso de la función FECHA.

=CONTAR.SI(A2:A50, ">" & PROMEDIO(A2:A50)) Número de celdas con valores superiores al promedio del rango.

=CONTAR.SI(A2:A50, "?????") Da el número de celdas que contienen exactamente cinco caracteres.

=CONTAR.SI(A2:A50, "abc*") Da el número de celdas que empiezan con "abc". No es sensible a mayúsculas

=CONTAR.SI(A2:A50, "*abc*") Da el número de celdas que contienen "abc". No es sensible a mayúsculas.

=CONTAR.SI(A2:A50, "??z*") Devuelve el número de celdas cuyo tercer caracter es "z".

=CONTAR.SI(A2:A50, FALSO) Cuenta las celdas que contienen el valor lógico FALSO.

=CONTAR.SI(A2:A50, "#!REF!") Cuenta el número de celdas que contienen el valor de error #!REF!

Desde luego, podemos combinar las técnicas de los ejemplos anteriores. También, podemos usar este tipo de criterios en otras funciones, como SUMAR.SI.

Esta nota pensaba titularla "En el pedir está el dar".